Singleton Factory

27th July 2007

I’ve mentioned before how I dislike the Singleton pattern. One of my issues is encapsulating the single instance nature of the pattern within the class, when most often the requirement for only one instance is not a feature of the class but a feature of the application that is using the class.

So this morning I was experimenting with various other possible ways to create singletons in Actionscript 3 and came up with a function that can be used to create and reuse a single instance of any class. I don’t know how useful it will turn out to be but here it is. It’s also a useful example of a package level function.

package
{
    function Singleton( c:Class ):*
    {
        for( var i:String in instances )
        {
            if( instances[i].constructor === c )
            {
                return instances[i];
            }
        }
        var obj:* = new c();
        instances.push( obj );
        return obj;
    }
}
var instances:Array = new Array();

You can use this function to create an instance of any class (your own or an intrinsic class) as follows (for example):

import flash.geom.Point;
var a:Point = Singleton( Point );

if you request another point elsewhere in your project, for example

import flash.geom.Point;
var b:Point = Singleton( Point );

you will get the same point back again.

The one problem is the need to loop through all previously created singletons looking for a match before creating a new one. The more singletons you create, the slower this will be. It’s probably fine since most applications only use a few singletons but it would be great to get a unique identifier directly from the class and then look up the matching singleton directly. I can get the class name via the toString method, but would also need the full package to ensure uniqueness. Any ideas?

Like I said, I’m not sure how useful this function will be but it’s here if anyone wants to use it. If you improve it then please let me know.

Postscript

In the comments below, Benny suggested a way to remove the loop, and so gain a more stable lookup time, by using a Dictionary instead of an Array. His suggestion, with minor alterations by me, looks like this.

package
{
   function Singleton( c:Class ):*
   {
      return c in instances ? instances[c] : instances[c] = new c();
   }
}
import flash.utils.Dictionary;
var instances:Dictionary = new Dictionary( false );

Thanks, Benny.

Be sociable:
digg reddit dzone stumble upon  del.icio.us blink list

Read more articles about Actionscript 3